Supprimer un message

Jean-Christophe

Voilà... Je te conseille de faire un "Edit" sur mon message pour reprendre le contenu, sinon, tu as les numéros des lignes ...

Code:

' Options :
'Lettre du lecteur
DriveLetter = "D"
'Chemin du fichier texte
TargetFile = "c:\catalogue.txt"
'Taille limite CD <-> DVD
MaxCDSize = 1000000000
'On crée les objets dont on va avoir besoin
'Le File System Object nous permet d'accéder aux répertoires, fichiers, etc.
Set FSO = CreateObject("Scripting.FileSystemObject")
ForReading = 1 : ForWriting = 2 : ForAppending = 8 : CreateIfNecessary = true : DontCreateIfNecessary = false
'On ouvre le fichier texte
Set TargetFileObject = FSO.OpenTextFile(TargetFile,ForAppending, CreateIfNecessary)
' On récupère une fois pour toutes le label du média
MediaLabel = FMediaLabel(DriveLetter)
' On récupère une fois pour toutes la taille du média
MediaSize = FMediaSize(DriveLetter)
If MediaSize > MaxCdSize then
MediaType = "DVD"
else
MediaType = "CD"
end if
i=0
'Lancement de la procédure
catalog FSO.GetFolder(DriveLetter & ":\")
' On ferme le Fichier Texte
TargetFileObject.Close()
'On donne le résulta
MsgBox "Catalogage Terminé. " & i & "répertoire(s) ajoutés"
'On Ejecte Le CD
opencd
'Procédures
'--------------
Sub catalog(Folder)
for each subfolder in Folder.subfolders
i=i+1
TargetFileObject.WriteLine(MediaLabel & "|" & MediaType & "|" & SubFolder.Name)
'Décommenter la ligne suivante pour faire une recherche récursive dans les sous-répertoires
'catalog FSO.GetFolder(subfolder.path)
next
End Sub
Function FMediaLabel(DriveLet)
Set colDrives = FSO.Drives
FMediaLabel = "No Label Found"
For Each objDrive in colDrives
if objDrive.DriveLetter = DriveLet then
FMediaLabel = objDrive.VolumeName
end if
Next
End Function
Function FMediaSize(DriveLet)
Set colDrives = FSO.Drives
For Each objDrive in colDrives
if objDrive.DriveLetter = DriveLet then
FMediaSize = objDrive.TotalSize
end if
Next
End Function
Sub opencd
Set oWMP = CreateObject("WMPlayer.OCX.7")
Set colCDROMs = oWMP.cdromCollection
For i = 0 To colCDROMs.count-1
colCDROMs.item(i).eject
Next
oWMP.close
End Sub

J'ai tout commenté, je vais continuer mes recherches sur la manière de déterminer le type de média.
Si je trouve quelque chose de concluant, je le poste :smile:

PS : C'est quoi l'OS des machines?